rem TEST.BAS
rem Hobby BASIC Interpreter
rem Saving and loading the screen
rem Using ANSI
rem Using GRAB/SAVE/LOAD
rem Using SNAP
rem Using BSAVE/BLOAD
path$ = PATH("DATA\TEMP")
if CHDIR(path$,0) = -1
if CHDIR(path$,1) <> 1
alert 0,"Can''t open",path$ : end
endif
endif
path$ = PATH("MEDIA\ANSI\SPACES1.ANS")
if SIZE(path$) = -1 then alert 0,"Not found",path$ : end
MB_ICONQUESTION = 0x20
MB_YESNO = 0x4
ID_YES = 0x6
SCREEN_WIDTH = 80
SCREEN_HEIGHT = 50
SCREEN_TO_ARRAY = 0
ARRAY_TO_SCREEN = 1
COLS = 15
ROWS = 12
rem declare arrays: robot0,robot1,...
for n = 0 to 4
dim robot//n[COLS,ROWS]
next
rem set ID array values: 700,701,...
dim ID[5] : ID[].SET 700
view 11
screen SCREEN_WIDTH,SCREEN_HEIGHT,0
cursor 0,0
color 0,0
cls
rem load an ANSI encoded text file
ansi path$
move 0,3,80,25,0,0
wait 500
rem SAVE SCREEN
rem screen to 2D array
rem GRAB with 6 parameters
grab 0,0,COLS,ROWS,robot0[],SCREEN_TO_ARRAY
grab 16,0,COLS,ROWS,robot1[],SCREEN_TO_ARRAY
grab 32,0,COLS,ROWS,robot2[],SCREEN_TO_ARRAY
grab 48,0,COLS,ROWS,robot3[],SCREEN_TO_ARRAY
grab 64,0,COLS,ROWS,robot4[],SCREEN_TO_ARRAY
rem 2D array to file (.HB extension)
save PATH("DATA\TEMP\ROBOT0.HB"),robot0[]
save PATH("DATA\TEMP\ROBOT1.HB"),robot1[]
save PATH("DATA\TEMP\ROBOT2.HB"),robot2[]
save PATH("DATA\TEMP\ROBOT3.HB"),robot3[]
save PATH("DATA\TEMP\ROBOT4.HB"),robot4[]
rem screen to file direct (.S extension)
rem SNAP with 5 parameters
snap 0,0,COLS,ROWS,PATH("DATA\TEMP\ROBOT0.S")
snap 16,0,COLS,ROWS,PATH("DATA\TEMP\ROBOT1.S")
snap 32,0,COLS,ROWS,PATH("DATA\TEMP\ROBOT2.S")
snap 48,0,COLS,ROWS,PATH("DATA\TEMP\ROBOT3.S")
snap 64,0,COLS,ROWS,PATH("DATA\TEMP\ROBOT4.S")
rem screen to memory
bsave 0,0,COLS,ROWS,ID[0]
bsave 16,0,COLS,ROWS,ID[1]
bsave 32,0,COLS,ROWS,ID[2]
bsave 48,0,COLS,ROWS,ID[3]
bsave 64,0,COLS,ROWS,ID[4]
rem LOAD SCREEN
rem zero arrays
for n = 0 to 4
robot//n[].ZERO
next
rem file to 2D array (.HB extension)
load PATH("DATA\TEMP\ROBOT0.HB"),robot0[]
load PATH("DATA\TEMP\ROBOT1.HB"),robot1[]
load PATH("DATA\TEMP\ROBOT2.HB"),robot2[]
load PATH("DATA\TEMP\ROBOT3.HB"),robot3[]
load PATH("DATA\TEMP\ROBOT4.HB"),robot4[]
rem 2D array to screen at position x,y
rem GRAB with 7 parameters
grab 0,0,COLS,ROWS,robot0[],0,12
grab 0,0,COLS,ROWS,robot1[],16,12
grab 0,0,COLS,ROWS,robot2[],32,12
grab 0,0,COLS,ROWS,robot3[],48,12
grab 0,0,COLS,ROWS,robot4[],64,12
wait 500
rem file to screen direct (.S extension)
rem SNAP with 3 parameters
snap 0,ROWS*2,PATH("DATA\TEMP\ROBOT0.S")
snap 16,ROWS*2,PATH("DATA\TEMP\ROBOT1.S")
snap 32,ROWS*2,PATH("DATA\TEMP\ROBOT2.S")
snap 48,ROWS*2,PATH("DATA\TEMP\ROBOT3.S")
snap 64,ROWS*2,PATH("DATA\TEMP\ROBOT4.S")
wait 500
rem shuffle ID array
ID[].SHUFFLE
rem memory to screen
rem robots appear in random position
bload 0,ROWS*3,ID[0]
bload 16,ROWS*3,ID[1]
bload 32,ROWS*3,ID[2]
bload 48,ROWS*3,ID[3]
bload 64,ROWS*3,ID[4]
wait 500
rem do some fancy changes
store 0,0,SCREEN_WIDTH,SCREEN_HEIGHT
times 5000 invert RND(SCREEN_WIDTH),RND(SCREEN_HEIGHT),1,1
restore
flip 16,ROWS*2,32,ROWS,0
flip 48,ROWS*2,16,ROWS,1
repaint 0,ROWS,SCREEN_WIDTH,ROWS,4,5
repaint 48,ROWS*2,16,ROWS,4,6
repaint 0,ROWS*3,SCREEN_WIDTH,ROWS,1,2
rem save the screen as ANSI encoded text file
V3 = -1
grab 0,0,SCREEN_WIDTH,SCREEN_HEIGHT-1,text$
path$ = PATH("MEDIA\ANSI\SPACES2.ANS")
save path$,text$
title "Press space to open the new image in DRAW, Esc to exit"
inkey
if V0 = 0x20
rem will fail if HB parent folder contains spaces, e.g, C:\NEW FOLDER\HB
cmd$ = "start /wait " + PATH("HB.EXE EXAMPLES\DRAW.BAS ") + path$
exec cmd$
endif
color 0,7 : cls : end
